1 files changed, 55 insertions, 40 deletions
diff --git a/src/irmd/CMakeLists.txt b/src/irmd/CMakeLists.txt
index 59d0d103..9aa747ca 100644
--- a/src/irmd/CMakeLists.txt
+++ b/src/irmd/CMakeLists.txt
@@ -1,52 +1,67 @@
-include_directories(${CMAKE_CURRENT_SOURCE_DIR})
-include_directories(${CMAKE_CURRENT_BINARY_DIR})
-
-include_directories(${CMAKE_SOURCE_DIR}/include)
-include_directories(${CMAKE_BINARY_DIR}/include)
-
-set(IRMD_REQ_ARR_TIMEOUT 500 CACHE STRING
-  "Timeout for an application to respond to a new flow (ms)")
-set(IRMD_FLOW_TIMEOUT 5000 CACHE STRING
-  "Timeout for a flow allocation response (ms)")
-set(BOOTSTRAP_TIMEOUT 5000 CACHE STRING
-  "Timeout for an IPCP to bootstrap (ms)")
-set(ENROLL_TIMEOUT 60000 CACHE STRING
-  "Timeout for an IPCP to enroll (ms)")
-set(REG_TIMEOUT 10000 CACHE STRING
-  "Timeout for registering a name (ms)")
-set(QUERY_TIMEOUT 3000 CACHE STRING
-  "Timeout to query a name with an IPCP (ms)")
-set(CONNECT_TIMEOUT 60000 CACHE STRING
-  "Timeout to connect an IPCP to another IPCP (ms)")
-set(IRMD_MIN_THREADS 8 CACHE STRING
-  "Minimum number of worker threads in the IRMd.")
-set(IRMD_ADD_THREADS 8 CACHE STRING
-  "Number of extra threads to start when the IRMD faces thread starvation")
+# IRMd (IPC Resource Manager daemon) build configuration
+# Configuration options are in cmake/config/global.cmake and cmake/config/irmd.cmake
+
+# Generate and install configuration files if TOML support available
+# HAVE_TOML is set in cmake/dependencies/irmd/libtoml.cmake
+if(HAVE_TOML)
+  set(INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_BINDIR}")
+  configure_file("${CMAKE_SOURCE_DIR}/irmd.conf.in"
+    "${CMAKE_BINARY_DIR}/${OUROBOROS_CONFIG_FILE}.example" @ONLY)
+  configure_file("${CMAKE_SOURCE_DIR}/enc.conf.in"
+    "${CMAKE_BINARY_DIR}/enc.conf.example" @ONLY)
+  install(FILES "${CMAKE_BINARY_DIR}/${OUROBOROS_CONFIG_FILE}.example"
+    DESTINATION "${OUROBOROS_CONFIG_DIR}")
+  install(FILES "${CMAKE_BINARY_DIR}/enc.conf.example"
+    DESTINATION "${OUROBOROS_CONFIG_DIR}")
+  install(CODE "
+    if(NOT EXISTS \"${OUROBOROS_CONFIG_DIR}/${OUROBOROS_CONFIG_FILE}\")
+      file(WRITE \"${OUROBOROS_CONFIG_DIR}/${OUROBOROS_CONFIG_FILE}\" \"\")
+    endif()
+  ")
+  unset(INSTALL_DIR)
+endif()
 
 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/config.h.in"
   "${CMAKE_CURRENT_BINARY_DIR}/config.h" @ONLY)
 
-set(SOURCE_FILES
-  # Add source files here
-  proc_table.c
-  prog_table.c
+set(IRMD_SOURCES
   ipcp.c
-  irm_flow.c
+  configfile.c
   main.c
-  registry.c
-  utils.c
-  )
+  oap/io.c
+  oap/hdr.c
+  oap/auth.c
+  oap/srv.c
+  oap/cli.c
+  reg/flow.c
+  reg/ipcp.c
+  reg/pool.c
+  reg/proc.c
+  reg/prog.c
+  reg/name.c
+  reg/reg.c
+)
+
+add_executable(irmd ${IRMD_SOURCES})
+
+add_dependencies(irmd version_header)
 
-add_executable (irmd ${SOURCE_FILES})
+target_include_directories(irmd PRIVATE
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_SOURCE_DIR}/include
+  ${CMAKE_BINARY_DIR}/include)
 
-target_link_libraries (irmd LINK_PUBLIC ouroboros-common)
+target_link_libraries(irmd PRIVATE ouroboros-common)
+if(HAVE_TOML)
+  target_link_libraries(irmd PRIVATE toml::toml)
+endif()
 
-include(AddCompileFlags)
-if (CMAKE_BUILD_TYPE MATCHES "Debug*")
-  add_compile_flags(irmd -DCONFIG_OUROBOROS_DEBUG)
-endif ()
+ouroboros_target_debug_definitions(irmd)
 
 install(TARGETS irmd RUNTIME DESTINATION ${CMAKE_INSTALL_SBINDIR})
 
-# Enable once irmd has tests
-# add_subdirectory(tests)
+if(BUILD_TESTS)
+  add_subdirectory(oap/tests)
+  add_subdirectory(reg/tests)
+endif()