build: Refactor CMake back to in-tree CMakeListsbe

This moves the build definitions back to src/ subdirectories
(CMakeLists.txt per component). Configuration and dependencies are
kept out of tree. Configuration options are bundled into cmake/config/
modules. Dependencies are grouped by component (system/, crypt/, eth/,
coverage/, etc.). It now consistently uses target-based commands
(target_include_directories, target_link_libraries) instead of global
include_directories(). Proper PRIVATE/PUBLIC visibility for executable
link libraries. CONFIG_OUROBOROS_DEBUG now properly set based on being
a valid debug config (not just checking the string name).

It also adds OuroborosTargets export for find_package() support and
CMake package config files (OuroborosConfig.cmake) for easier
integration with CMake projects.

The build logic now follows more idiomatic CMake practices with
configuration separated from target definitions.

Signed-off-by: Dimitri Staessens <dimitri@ouroboros.rocks>
Signed-off-by: Sander Vrijders <sander@ouroboros.rocks>

17 files changed, 541 insertions, 174 deletions

diff --git a/src/ipcpd/CMakeLists.txt b/src/ipcpd/CMakeLists.txt
new file mode 100644
index 00000000..609da54a
--- /dev/null
+++ b/src/ipcpd/CMakeLists.txt
@@ -0,0 +1,30 @@
+# IPCP (IPC Process) daemons build configuration
+# Configuration options and validation are in cmake/config/ipcp/*.cmake
+
+# Common sources shared by all IPCPs (absolute paths for subdirectories)
+set(IPCP_SOURCES
+  ${CMAKE_CURRENT_SOURCE_DIR}/ipcp.c
+  ${CMAKE_CURRENT_SOURCE_DIR}/shim-data.c
+)
+
+set(COMMON_SOURCES
+  ${CMAKE_CURRENT_SOURCE_DIR}/common/enroll.c
+)
+
+set(IPCP_INCLUDE_DIRS
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_SOURCE_DIR}/include
+  ${CMAKE_BINARY_DIR}/include
+)
+
+configure_file("${CMAKE_CURRENT_SOURCE_DIR}/config.h.in"
+  "${CMAKE_CURRENT_BINARY_DIR}/config.h" @ONLY)
+
+add_subdirectory(local)
+add_subdirectory(broadcast)
+add_subdirectory(unicast)
+if(HAVE_ETH)
+  add_subdirectory(eth)
+endif()
+add_subdirectory(udp)
diff --git a/src/ipcpd/broadcast/CMakeLists.txt b/src/ipcpd/broadcast/CMakeLists.txt
new file mode 100644
index 00000000..433d9979
--- /dev/null
+++ b/src/ipcpd/broadcast/CMakeLists.txt
@@ -0,0 +1,22 @@
+# Broadcast IPCP build configuration
+
+set(IPCP_BROADCAST_TARGET ipcpd-broadcast)
+
+set(BROADCAST_SOURCES
+  connmgr.c
+  dt.c
+  main.c
+)
+
+add_executable(${IPCP_BROADCAST_TARGET}
+  ${BROADCAST_SOURCES}
+  ${IPCP_SOURCES}
+  ${COMMON_SOURCES}
+)
+
+target_include_directories(${IPCP_BROADCAST_TARGET} PRIVATE ${IPCP_INCLUDE_DIRS})
+target_link_libraries(${IPCP_BROADCAST_TARGET} PRIVATE ouroboros-dev)
+
+ouroboros_target_debug_definitions(${IPCP_BROADCAST_TARGET})
+
+install(TARGETS ${IPCP_BROADCAST_TARGET} RUNTIME DESTINATION ${CMAKE_INSTALL_SBINDIR})
diff --git a/src/ipcpd/eth/CMakeLists.txt b/src/ipcpd/eth/CMakeLists.txt
new file mode 100644
index 00000000..e6cc8224
--- /dev/null
+++ b/src/ipcpd/eth/CMakeLists.txt
@@ -0,0 +1,24 @@
+# Ethernet IPCPs build configuration (LLC and DIX)
+# HAVE_ETH detection is in cmake/dependencies.cmake
+
+set(IPCP_ETH_LLC_TARGET ipcpd-eth-llc)
+set(IPCP_ETH_DIX_TARGET ipcpd-eth-dix)
+
+add_executable(${IPCP_ETH_LLC_TARGET} llc.c ${IPCP_SOURCES})
+add_executable(${IPCP_ETH_DIX_TARGET} dix.c ${IPCP_SOURCES})
+
+foreach(target ${IPCP_ETH_LLC_TARGET} ${IPCP_ETH_DIX_TARGET})
+  target_include_directories(${target} PRIVATE ${IPCP_INCLUDE_DIRS})
+  if(HAVE_BPF AND NOT APPLE)
+    target_include_directories(${target} PRIVATE ${BPF_C_INCLUDE_DIR})
+  endif()
+  if(HAVE_NETMAP AND NOT APPLE)
+    target_compile_options(${target} PRIVATE -std=c99)
+    target_include_directories(${target} PRIVATE ${NETMAP_C_INCLUDE_DIR})
+  endif()
+  target_link_libraries(${target} PRIVATE ouroboros-dev)
+  ouroboros_target_debug_definitions(${target})
+endforeach()
+
+install(TARGETS ${IPCP_ETH_LLC_TARGET} ${IPCP_ETH_DIX_TARGET}
+        RUNTIME DESTINATION ${CMAKE_INSTALL_SBINDIR})
diff --git a/src/ipcpd/local/CMakeLists.txt b/src/ipcpd/local/CMakeLists.txt
new file mode 100644
index 00000000..0da4d47a
--- /dev/null
+++ b/src/ipcpd/local/CMakeLists.txt
@@ -0,0 +1,19 @@
+# Local IPCP build configuration
+
+set(IPCP_LOCAL_TARGET ipcpd-local)
+
+add_executable(${IPCP_LOCAL_TARGET}
+  main.c
+  ${IPCP_SOURCES}
+)
+
+target_include_directories(${IPCP_LOCAL_TARGET} PRIVATE ${IPCP_INCLUDE_DIRS})
+target_link_libraries(${IPCP_LOCAL_TARGET} PRIVATE ouroboros-dev)
+
+ouroboros_target_debug_definitions(${IPCP_LOCAL_TARGET})
+
+if(IPCP_LOCAL_POLLING)
+  target_compile_definitions(${IPCP_LOCAL_TARGET} PRIVATE CONFIG_IPCP_LOCAL_POLLING)
+endif()
+
+install(TARGETS ${IPCP_LOCAL_TARGET} RUNTIME DESTINATION ${CMAKE_INSTALL_SBINDIR})
diff --git a/src/ipcpd/udp/CMakeLists.txt b/src/ipcpd/udp/CMakeLists.txt
new file mode 100644
index 00000000..159e9bf5
--- /dev/null
+++ b/src/ipcpd/udp/CMakeLists.txt
@@ -0,0 +1,17 @@
+# UDP IPCPs build configuration (UDP4 and UDP6)
+# DDNS detection is in cmake/dependencies/udp/ddns.cmake
+
+set(IPCP_UDP4_TARGET ipcpd-udp4)
+set(IPCP_UDP6_TARGET ipcpd-udp6)
+
+add_executable(${IPCP_UDP4_TARGET} udp4.c ${IPCP_SOURCES})
+add_executable(${IPCP_UDP6_TARGET} udp6.c ${IPCP_SOURCES})
+
+foreach(target ${IPCP_UDP4_TARGET} ${IPCP_UDP6_TARGET})
+  target_include_directories(${target} PRIVATE ${IPCP_INCLUDE_DIRS})
+  target_link_libraries(${target} PRIVATE ouroboros-dev)
+  ouroboros_target_debug_definitions(${target})
+endforeach()
+
+install(TARGETS ${IPCP_UDP4_TARGET} ${IPCP_UDP6_TARGET}
+        RUNTIME DESTINATION ${CMAKE_INSTALL_SBINDIR})
diff --git a/src/ipcpd/unicast/CMakeLists.txt b/src/ipcpd/unicast/CMakeLists.txt
new file mode 100644
index 00000000..1e095f8b
--- /dev/null
+++ b/src/ipcpd/unicast/CMakeLists.txt
@@ -0,0 +1,51 @@
+# Unicast IPCP build configuration
+
+set(IPCP_UNICAST_TARGET ipcpd-unicast)
+
+protobuf_generate_c(DHT_PROTO_SRCS DHT_PROTO_HDRS
+  "${CMAKE_CURRENT_SOURCE_DIR}/dir/dht.proto")
+
+set(UNICAST_SOURCES
+  addr-auth.c
+  ca.c
+  connmgr.c
+  dir.c
+  dt.c
+  fa.c
+  main.c
+  pff.c
+  routing.c
+  psched.c
+  addr-auth/flat.c
+  ca/mb-ecn.c
+  ca/nop.c
+  dir/dht.c
+  pff/simple.c
+  pff/alternate.c
+  pff/multipath.c
+  pff/pft.c
+  routing/link-state.c
+  routing/graph.c
+)
+
+add_executable(${IPCP_UNICAST_TARGET}
+  ${UNICAST_SOURCES}
+  ${IPCP_SOURCES}
+  ${COMMON_SOURCES}
+  ${DHT_PROTO_SRCS}
+)
+
+target_include_directories(${IPCP_UNICAST_TARGET} PRIVATE ${IPCP_INCLUDE_DIRS})
+target_include_directories(${IPCP_UNICAST_TARGET} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR})
+target_include_directories(${IPCP_UNICAST_TARGET} PRIVATE ${CMAKE_CURRENT_BINARY_DIR})
+target_link_libraries(${IPCP_UNICAST_TARGET} PRIVATE ouroboros-dev)
+
+ouroboros_target_debug_definitions(${IPCP_UNICAST_TARGET})
+
+install(TARGETS ${IPCP_UNICAST_TARGET} RUNTIME DESTINATION ${CMAKE_INSTALL_SBINDIR})
+
+if(BUILD_TESTS)
+  add_subdirectory(dir/tests)
+  add_subdirectory(pff/tests)
+  add_subdirectory(routing/tests)
+endif()
diff --git a/src/ipcpd/unicast/dir/tests/CMakeLists.txt b/src/ipcpd/unicast/dir/tests/CMakeLists.txt
index dd15d4d8..eded823f 100644
--- a/src/ipcpd/unicast/dir/tests/CMakeLists.txt
+++ b/src/ipcpd/unicast/dir/tests/CMakeLists.txt
@@ -3,21 +3,6 @@ get_filename_component(CURRENT_SOURCE_PARENT_DIR
 get_filename_component(CURRENT_BINARY_PARENT_DIR
   ${CMAKE_CURRENT_BINARY_DIR} DIRECTORY)
 
-include_directories(${CMAKE_CURRENT_SOURCE_DIR})
-include_directories(${CMAKE_CURRENT_BINARY_DIR})
-
-include_directories(${CURRENT_SOURCE_PARENT_DIR})
-include_directories(${CURRENT_BINARY_PARENT_DIR})
-
-include_directories(${CMAKE_SOURCE_DIR}/include)
-include_directories(${CMAKE_BINARY_DIR}/include)
-
-# Add includes for ipcp and unicast module files
-include_directories(${CMAKE_SOURCE_DIR}/src/ipcpd)
-include_directories(${CMAKE_BINARY_DIR}/src/ipcpd)
-include_directories(${CMAKE_SOURCE_DIR}/src/ipcpd/unicast)
-include_directories(${CMAKE_BINARY_DIR}/src/ipcpd/unicast)
-
 get_filename_component(PARENT_PATH ${CMAKE_CURRENT_SOURCE_DIR} DIRECTORY)
 get_filename_component(PARENT_DIR ${PARENT_PATH} NAME)
 
@@ -26,25 +11,28 @@ compute_test_prefix()
 create_test_sourcelist(${PARENT_DIR}_tests test_suite.c
   # Add new tests here
   dht_test.c
-  )
+)
 
 protobuf_generate_c(DHT_PROTO_SRCS KAD_PROTO_HDRS ${CURRENT_SOURCE_PARENT_DIR}/dht.proto)
 add_executable(${PARENT_DIR}_test ${${PARENT_DIR}_tests}
   ${DHT_PROTO_SRCS})
 
+target_include_directories(${PARENT_DIR}_test PRIVATE
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CURRENT_SOURCE_PARENT_DIR}
+  ${CURRENT_BINARY_PARENT_DIR}
+  ${CMAKE_SOURCE_DIR}/include
+  ${CMAKE_BINARY_DIR}/include
+  ${CMAKE_SOURCE_DIR}/src/ipcpd
+  ${CMAKE_BINARY_DIR}/src/ipcpd
+  ${CMAKE_SOURCE_DIR}/src/ipcpd/unicast
+  ${CMAKE_BINARY_DIR}/src/ipcpd/unicast
+)
+
 disable_test_logging_for_target(${PARENT_DIR}_test)
 
 target_link_libraries(${PARENT_DIR}_test ouroboros-common)
 add_dependencies(build_tests ${PARENT_DIR}_test)
 
-set(tests_to_run ${${PARENT_DIR}_tests})
-if(CMAKE_VERSION VERSION_LESS "3.29.0")
-  remove(tests_to_run test_suite.c)
-else ()
-  list(POP_FRONT tests_to_run)
-endif()
-
-foreach (test ${tests_to_run})
-  get_filename_component(test_name ${test} NAME_WE)
-  add_test(${TEST_PREFIX}/${test_name} ${C_TEST_PATH}/${PARENT_DIR}_test ${test_name})
-endforeach (test)
+ouroboros_register_tests(TARGET ${PARENT_DIR}_test TESTS ${${PARENT_DIR}_tests})
diff --git a/src/ipcpd/unicast/pff/tests/CMakeLists.txt b/src/ipcpd/unicast/pff/tests/CMakeLists.txt
index ccca26a0..8c0e3d51 100644
--- a/src/ipcpd/unicast/pff/tests/CMakeLists.txt
+++ b/src/ipcpd/unicast/pff/tests/CMakeLists.txt
@@ -3,19 +3,6 @@ get_filename_component(CURRENT_SOURCE_PARENT_DIR
 get_filename_component(CURRENT_BINARY_PARENT_DIR
   ${CMAKE_CURRENT_BINARY_DIR} DIRECTORY)
 
-include_directories(${CMAKE_CURRENT_SOURCE_DIR})
-include_directories(${CMAKE_CURRENT_BINARY_DIR})
-
-include_directories(${CURRENT_SOURCE_PARENT_DIR})
-include_directories(${CURRENT_BINARY_PARENT_DIR})
-
-include_directories(${CMAKE_SOURCE_DIR}/include)
-include_directories(${CMAKE_BINARY_DIR}/include)
-
-# Add includes for ipcp module files
-include_directories(${CMAKE_SOURCE_DIR}/src/ipcpd)
-include_directories(${CMAKE_BINARY_DIR}/src/ipcpd)
-
 get_filename_component(PARENT_PATH ${CMAKE_CURRENT_SOURCE_DIR} DIRECTORY)
 get_filename_component(PARENT_DIR ${PARENT_PATH} NAME)
 
@@ -27,19 +14,21 @@ create_test_sourcelist(${PARENT_DIR}_tests test_suite.c
   )
 
 add_executable(${PARENT_DIR}_test ${${PARENT_DIR}_tests})
+
+target_include_directories(${PARENT_DIR}_test PRIVATE
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CURRENT_SOURCE_PARENT_DIR}
+  ${CURRENT_BINARY_PARENT_DIR}
+  ${CMAKE_SOURCE_DIR}/include
+  ${CMAKE_BINARY_DIR}/include
+  ${CMAKE_SOURCE_DIR}/src/ipcpd
+  ${CMAKE_BINARY_DIR}/src/ipcpd
+)
+
 disable_test_logging_for_target(${PARENT_DIR}_test)
-target_link_libraries(${PARENT_DIR}_test ouroboros-common)
+target_link_libraries(${PARENT_DIR}_test PRIVATE ouroboros-common)
 
 add_dependencies(build_tests ${PARENT_DIR}_test)
 
-set(tests_to_run ${${PARENT_DIR}_tests})
-if(CMAKE_VERSION VERSION_LESS "3.29.0")
-  remove(tests_to_run test_suite.c)
-else ()
-  list(POP_FRONT tests_to_run)
-endif()
-
-foreach (test ${tests_to_run})
-  get_filename_component(test_name ${test} NAME_WE)
-  add_test(${TEST_PREFIX}/${test_name} ${CMAKE_CURRENT_BINARY_DIR}/${PARENT_DIR}_test ${test_name})
-endforeach (test)
+ouroboros_register_tests(TARGET ${PARENT_DIR}_test TESTS ${${PARENT_DIR}_tests})
diff --git a/src/ipcpd/unicast/routing/tests/CMakeLists.txt b/src/ipcpd/unicast/routing/tests/CMakeLists.txt
index f97d03bb..be2de72c 100644
--- a/src/ipcpd/unicast/routing/tests/CMakeLists.txt
+++ b/src/ipcpd/unicast/routing/tests/CMakeLists.txt
@@ -3,18 +3,6 @@ get_filename_component(CURRENT_SOURCE_PARENT_DIR
 get_filename_component(CURRENT_BINARY_PARENT_DIR
   ${CMAKE_CURRENT_BINARY_DIR} DIRECTORY)
 
-include_directories(${CMAKE_CURRENT_SOURCE_DIR})
-include_directories(${CMAKE_CURRENT_BINARY_DIR})
-
-include_directories(${CURRENT_SOURCE_PARENT_DIR})
-include_directories(${CURRENT_BINARY_PARENT_DIR})
-
-include_directories(${CMAKE_SOURCE_DIR}/include)
-include_directories(${CMAKE_BINARY_DIR}/include)
-
-include_directories(${CMAKE_SOURCE_DIR}/src/ipcpd)
-include_directories(${CMAKE_BINARY_DIR}/src/ipcpd)
-
 get_filename_component(PARENT_PATH ${CMAKE_CURRENT_SOURCE_DIR} DIRECTORY)
 get_filename_component(PARENT_DIR ${PARENT_PATH} NAME)
 
@@ -27,19 +15,20 @@ create_test_sourcelist(${PARENT_DIR}_tests test_suite.c
 
 add_executable(${PARENT_DIR}_test ${${PARENT_DIR}_tests})
 
+target_include_directories(${PARENT_DIR}_test PRIVATE
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CURRENT_SOURCE_PARENT_DIR}
+  ${CURRENT_BINARY_PARENT_DIR}
+  ${CMAKE_SOURCE_DIR}/include
+  ${CMAKE_BINARY_DIR}/include
+  ${CMAKE_SOURCE_DIR}/src/ipcpd
+  ${CMAKE_BINARY_DIR}/src/ipcpd
+)
+
 disable_test_logging_for_target(${PARENT_DIR}_test)
-target_link_libraries(${PARENT_DIR}_test ouroboros-common)
+target_link_libraries(${PARENT_DIR}_test PRIVATE ouroboros-common)
 
 add_dependencies(build_tests ${PARENT_DIR}_test)
 
-set(tests_to_run ${${PARENT_DIR}_tests})
-if(CMAKE_VERSION VERSION_LESS "3.29.0")
-  remove(tests_to_run test_suite.c)
-else ()
-  list(POP_FRONT tests_to_run)
-endif()
-
-foreach (test ${tests_to_run})
-  get_filename_component(test_name ${test} NAME_WE)
-  add_test(${TEST_PREFIX}/${test_name} ${C_TEST_PATH}/${PARENT_DIR}_test ${test_name})
-endforeach (test)
+ouroboros_register_tests(TARGET ${PARENT_DIR}_test TESTS ${${PARENT_DIR}_tests})
diff --git a/src/irmd/CMakeLists.txt b/src/irmd/CMakeLists.txt
new file mode 100644
index 00000000..d65635af
--- /dev/null
+++ b/src/irmd/CMakeLists.txt
@@ -0,0 +1,65 @@
+# IRMd (IPC Resource Manager daemon) build configuration
+# Configuration options are in cmake/config/global.cmake and cmake/config/irmd.cmake
+
+# Generate and install configuration files if TOML support available
+# HAVE_TOML is set in cmake/dependencies/irmd/libtoml.cmake
+if(HAVE_TOML)
+  set(INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_BINDIR}")
+  configure_file("${CMAKE_SOURCE_DIR}/irmd.conf.in"
+    "${CMAKE_BINARY_DIR}/${OUROBOROS_CONFIG_FILE}.example" @ONLY)
+  configure_file("${CMAKE_SOURCE_DIR}/enc.conf.in"
+    "${CMAKE_BINARY_DIR}/enc.conf.example" @ONLY)
+  install(FILES "${CMAKE_BINARY_DIR}/${OUROBOROS_CONFIG_FILE}.example"
+    DESTINATION "${OUROBOROS_CONFIG_DIR}")
+  install(FILES "${CMAKE_BINARY_DIR}/enc.conf.example"
+    DESTINATION "${OUROBOROS_CONFIG_DIR}")
+  install(CODE "
+    if(NOT EXISTS \"${OUROBOROS_CONFIG_DIR}/${OUROBOROS_CONFIG_FILE}\")
+      file(WRITE \"${OUROBOROS_CONFIG_DIR}/${OUROBOROS_CONFIG_FILE}\" \"\")
+    endif()
+  ")
+  unset(INSTALL_DIR)
+endif()
+
+configure_file("${CMAKE_CURRENT_SOURCE_DIR}/config.h.in"
+  "${CMAKE_CURRENT_BINARY_DIR}/config.h" @ONLY)
+
+set(IRMD_SOURCES
+  ipcp.c
+  configfile.c
+  main.c
+  oap/io.c
+  oap/hdr.c
+  oap/auth.c
+  oap/srv.c
+  oap/cli.c
+  reg/flow.c
+  reg/ipcp.c
+  reg/pool.c
+  reg/proc.c
+  reg/prog.c
+  reg/name.c
+  reg/reg.c
+)
+
+add_executable(irmd ${IRMD_SOURCES})
+
+target_include_directories(irmd PRIVATE
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_SOURCE_DIR}/include
+  ${CMAKE_BINARY_DIR}/include)
+
+target_link_libraries(irmd PRIVATE ouroboros-common)
+if(HAVE_TOML)
+  target_link_libraries(irmd PRIVATE toml::toml)
+endif()
+
+ouroboros_target_debug_definitions(irmd)
+
+install(TARGETS irmd RUNTIME DESTINATION ${CMAKE_INSTALL_SBINDIR})
+
+if(BUILD_TESTS)
+  add_subdirectory(oap/tests)
+  add_subdirectory(reg/tests)
+endif()
diff --git a/src/irmd/oap/tests/CMakeLists.txt b/src/irmd/oap/tests/CMakeLists.txt
index 2e8f1319..2bf23821 100644
--- a/src/irmd/oap/tests/CMakeLists.txt
+++ b/src/irmd/oap/tests/CMakeLists.txt
@@ -1,5 +1,5 @@
-get_filename_component(tmp ".." ABSOLUTE)
-get_filename_component(src_folder "${tmp}" NAME)
+get_filename_component(PARENT_PATH ${CMAKE_CURRENT_SOURCE_DIR} DIRECTORY)
+get_filename_component(PARENT_DIR ${PARENT_PATH} NAME)
 
 get_filename_component(OAP_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}" DIRECTORY)
 get_filename_component(OAP_BINARY_DIR "${CMAKE_CURRENT_BINARY_DIR}" DIRECTORY)
@@ -8,12 +8,12 @@ get_filename_component(IRMD_BINARY_DIR "${OAP_BINARY_DIR}" DIRECTORY)
 
 compute_test_prefix()
 
-create_test_sourcelist(${src_folder}_tests test_suite.c
+create_test_sourcelist(${PARENT_DIR}_tests test_suite.c
   # Add new tests here
   oap_test.c
 )
 
-create_test_sourcelist(${src_folder}_pqc_tests test_suite_pqc.c
+create_test_sourcelist(${PARENT_DIR}_pqc_tests test_suite_pqc.c
   # PQC-specific tests
   oap_test_pqc.c
 )
@@ -29,59 +29,36 @@ set(OAP_TEST_SOURCES
 )
 
 # Regular test executable (ECDSA)
-add_executable(${src_folder}_test ${${src_folder}_tests} ${OAP_TEST_SOURCES})
+add_executable(${PARENT_DIR}_test ${${PARENT_DIR}_tests} ${OAP_TEST_SOURCES})
 set_source_files_properties(${OAP_TEST_SOURCES}
   PROPERTIES COMPILE_DEFINITIONS "OAP_TEST_MODE"
 )
 
-disable_test_logging_for_target(${src_folder}_test)
-target_link_libraries(${src_folder}_test ouroboros-irm)
-target_include_directories(${src_folder}_test PRIVATE
+disable_test_logging_for_target(${PARENT_DIR}_test)
+target_link_libraries(${PARENT_DIR}_test ouroboros-irm)
+target_include_directories(${PARENT_DIR}_test PRIVATE
   ${IRMD_SOURCE_DIR}
   ${IRMD_BINARY_DIR}
 )
 
 # PQC test executable (ML-DSA)
-add_executable(${src_folder}_pqc_test ${${src_folder}_pqc_tests} ${OAP_TEST_SOURCES})
+add_executable(${PARENT_DIR}_pqc_test ${${PARENT_DIR}_pqc_tests} ${OAP_TEST_SOURCES})
 set_source_files_properties(${OAP_TEST_SOURCES}
-  TARGET_DIRECTORY ${src_folder}_pqc_test
+  TARGET_DIRECTORY ${PARENT_DIR}_pqc_test
   PROPERTIES COMPILE_DEFINITIONS "OAP_TEST_MODE"
 )
 
-disable_test_logging_for_target(${src_folder}_pqc_test)
-target_link_libraries(${src_folder}_pqc_test ouroboros-irm)
-target_include_directories(${src_folder}_pqc_test PRIVATE
+disable_test_logging_for_target(${PARENT_DIR}_pqc_test)
+target_link_libraries(${PARENT_DIR}_pqc_test ouroboros-irm)
+target_include_directories(${PARENT_DIR}_pqc_test PRIVATE
   ${IRMD_SOURCE_DIR}
   ${IRMD_BINARY_DIR}
 )
 
-add_dependencies(build_tests ${src_folder}_test ${src_folder}_pqc_test)
+add_dependencies(build_tests ${PARENT_DIR}_test ${PARENT_DIR}_pqc_test)
 
 # Regular tests
-set(tests_to_run ${${src_folder}_tests})
-if(CMAKE_VERSION VERSION_LESS "3.29.0")
-  remove(tests_to_run test_suite.c)
-else ()
-  list(POP_FRONT tests_to_run)
-endif()
-
-foreach(test ${tests_to_run})
-  get_filename_component(test_name ${test} NAME_WE)
-  add_test(${TEST_PREFIX}/${test_name} ${CMAKE_CURRENT_BINARY_DIR}/${src_folder}_test ${test_name})
-endforeach(test)
+ouroboros_register_tests(TARGET ${PARENT_DIR}_test TESTS ${${PARENT_DIR}_tests})
 
 # PQC tests
-set(pqc_tests_to_run ${${src_folder}_pqc_tests})
-if(CMAKE_VERSION VERSION_LESS "3.29.0")
-  remove(pqc_tests_to_run test_suite_pqc.c)
-else ()
-  list(POP_FRONT pqc_tests_to_run)
-endif()
-
-foreach(test ${pqc_tests_to_run})
-  get_filename_component(test_name ${test} NAME_WE)
-  add_test(${TEST_PREFIX}/${test_name} ${CMAKE_CURRENT_BINARY_DIR}/${src_folder}_pqc_test ${test_name})
-endforeach(test)
-
-set_property(TEST ${TEST_PREFIX}/oap_test PROPERTY SKIP_RETURN_CODE 1)
-set_property(TEST ${TEST_PREFIX}/oap_test_pqc PROPERTY SKIP_RETURN_CODE 1)
+ouroboros_register_tests(TARGET ${PARENT_DIR}_pqc_test TESTS ${${PARENT_DIR}_pqc_tests})
diff --git a/src/irmd/reg/tests/CMakeLists.txt b/src/irmd/reg/tests/CMakeLists.txt
index 759d29b4..e8521545 100644
--- a/src/irmd/reg/tests/CMakeLists.txt
+++ b/src/irmd/reg/tests/CMakeLists.txt
@@ -1,17 +1,9 @@
-get_filename_component(tmp ".." ABSOLUTE)
-get_filename_component(src_folder "${tmp}" NAME)
+get_filename_component(PARENT_PATH ${CMAKE_CURRENT_SOURCE_DIR} DIRECTORY)
+get_filename_component(PARENT_DIR ${PARENT_PATH} NAME)
 
 compute_test_prefix()
 
-# Set include directories for tests
-include_directories(${CMAKE_CURRENT_SOURCE_DIR})
-include_directories(${CMAKE_CURRENT_BINARY_DIR})
-include_directories(${CMAKE_SOURCE_DIR}/include)
-include_directories(${CMAKE_BINARY_DIR}/include)
-include_directories(${CMAKE_SOURCE_DIR}/src/irmd)
-include_directories(${CMAKE_BINARY_DIR}/src/irmd)
-
-create_test_sourcelist(${src_folder}_tests test_suite.c
+create_test_sourcelist(${PARENT_DIR}_tests test_suite.c
   # Add new tests here
   flow_test.c
   ipcp_test.c
@@ -21,25 +13,21 @@ create_test_sourcelist(${src_folder}_tests test_suite.c
   reg_test.c
 )
 
-add_executable(${src_folder}_test ${${src_folder}_tests})
-
-disable_test_logging_for_target(${src_folder}_test)
-target_link_libraries(${src_folder}_test ouroboros-common)
+add_executable(${PARENT_DIR}_test ${${PARENT_DIR}_tests})
 
-if (CMAKE_BUILD_TYPE MATCHES "Debug*")
-  add_compile_flags(${src_folder}_test -DCONFIG_OUROBOROS_DEBUG)
-endif ()
+target_include_directories(${PARENT_DIR}_test PRIVATE
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_SOURCE_DIR}/include
+  ${CMAKE_BINARY_DIR}/include
+  ${CMAKE_SOURCE_DIR}/src/irmd
+  ${CMAKE_BINARY_DIR}/src/irmd
+)
 
-add_dependencies(build_tests ${src_folder}_test)
+disable_test_logging_for_target(${PARENT_DIR}_test)
+target_link_libraries(${PARENT_DIR}_test PRIVATE ouroboros-common)
+ouroboros_target_debug_definitions(${PARENT_DIR}_test)
 
-set(tests_to_run ${${src_folder}_tests})
-if(CMAKE_VERSION VERSION_LESS "3.29.0")
-  remove(tests_to_run test_suite.c)
-else ()
-  list(POP_FRONT tests_to_run)
-endif()
+add_dependencies(build_tests ${PARENT_DIR}_test)
 
-foreach(test ${tests_to_run})
-  get_filename_component(test_name ${test} NAME_WE)
-  add_test(${TEST_PREFIX}/${test_name} ${CMAKE_CURRENT_BINARY_DIR}/${src_folder}_test ${test_name})
-endforeach(test)
+ouroboros_register_tests(TARGET ${PARENT_DIR}_test TESTS ${${PARENT_DIR}_tests})
diff --git a/src/lib/CMakeLists.txt b/src/lib/CMakeLists.txt
new file mode 100644
index 00000000..c4306b00
--- /dev/null
+++ b/src/lib/CMakeLists.txt
@@ -0,0 +1,160 @@
+# Ouroboros libraries build configuration
+# Configuration options are in cmake/config/lib.cmake
+
+protobuf_generate_c(MODEL_PROTO_SRCS MODEL_PROTO_HDRS
+  "${CMAKE_CURRENT_SOURCE_DIR}/pb/model.proto")
+protobuf_generate_c(IPCP_CONFIG_PROTO_SRCS IPCP_CONFIG_PROTO_HDRS
+  "${CMAKE_CURRENT_SOURCE_DIR}/pb/ipcp_config.proto")
+protobuf_generate_c(ENROLL_PROTO_SRCS ENROLL_PROTO_HDRS
+  "${CMAKE_CURRENT_SOURCE_DIR}/pb/enroll.proto")
+protobuf_generate_c(CEP_PROTO_SRCS CEP_PROTO_HDRS
+  "${CMAKE_CURRENT_SOURCE_DIR}/pb/cep.proto")
+protobuf_generate_c(IRM_PROTO_SRCS IRM_PROTO_HDRS
+  "${CMAKE_CURRENT_SOURCE_DIR}/pb/irm.proto")
+protobuf_generate_c(IPCP_PROTO_SRCS IPCP_PROTO_HDRS
+  "${CMAKE_CURRENT_SOURCE_DIR}/pb/ipcp.proto")
+
+set(SOURCE_FILES_COMMON
+  bitmap.c
+  btree.c
+  crc32.c
+  crypt.c
+  hash.c
+  list.c
+  lockfile.c
+  logs.c
+  md5.c
+  notifier.c
+  protobuf.c
+  qoscube.c
+  random.c
+  rib.c
+  serdes-irm.c
+  serdes-oep.c
+  sha3.c
+  ssm/flow_set.c
+  ssm/rbuff.c
+  ssm/pool.c
+  sockets.c
+  tpm.c
+  utils.c
+)
+
+if(HAVE_OPENSSL)
+  list(APPEND SOURCE_FILES_COMMON crypt/openssl.c)
+endif()
+
+add_library(ouroboros-common SHARED
+  ${SOURCE_FILES_COMMON}
+  ${IRM_PROTO_SRCS}
+  ${IPCP_PROTO_SRCS}
+  ${IPCP_CONFIG_PROTO_SRCS}
+  ${MODEL_PROTO_SRCS}
+  ${ENROLL_PROTO_SRCS})
+
+set_target_properties(ouroboros-common PROPERTIES
+  VERSION ${PACKAGE_VERSION}
+  SOVERSION ${PACKAGE_VERSION_MAJOR}.${PACKAGE_VERSION_MINOR})
+
+ouroboros_target_debug_definitions(ouroboros-common)
+
+target_include_directories(ouroboros-common
+  PUBLIC
+    $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
+    $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include>
+    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
+    $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
+    $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}>
+    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
+  PRIVATE
+    ${SYS_RND_HDR}
+    ${APPLE_INCLUDE_DIRS})
+
+target_link_libraries(ouroboros-common
+  PRIVATE
+    ${LIBRT_LIBRARIES}
+    Threads::Threads
+  PUBLIC
+    ProtobufC::ProtobufC)
+
+if(HAVE_OPENSSL)
+  target_link_libraries(ouroboros-common PUBLIC OpenSSL::Crypto)
+endif()
+
+if(HAVE_LIBGCRYPT)
+  target_link_libraries(ouroboros-common PUBLIC Gcrypt::Gcrypt)
+endif()
+
+if(HAVE_FUSE)
+  target_link_libraries(ouroboros-common PRIVATE Fuse::Fuse)
+endif()
+
+install(TARGETS ouroboros-common
+  EXPORT OuroborosTargets
+  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
+
+set(SOURCE_FILES_DEV
+  cep.c
+  dev.c
+)
+
+add_library(ouroboros-dev SHARED
+  ${SOURCE_FILES_DEV}
+  ${CEP_PROTO_SRCS})
+
+set_target_properties(ouroboros-dev PROPERTIES
+  VERSION ${PACKAGE_VERSION}
+  SOVERSION ${PACKAGE_VERSION_MAJOR}.${PACKAGE_VERSION_MINOR})
+
+ouroboros_target_debug_definitions(ouroboros-dev)
+
+target_include_directories(ouroboros-dev
+  PUBLIC
+    $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
+    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
+  PRIVATE
+    ${CMAKE_CURRENT_SOURCE_DIR}
+    ${CMAKE_CURRENT_BINARY_DIR}
+    ${CMAKE_BINARY_DIR}
+    ${SYS_RND_HDR})
+
+target_link_libraries(ouroboros-dev PUBLIC ouroboros-common)
+
+install(TARGETS ouroboros-dev
+  EXPORT OuroborosTargets
+  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
+
+add_library(ouroboros-irm SHARED irm.c)
+
+set_target_properties(ouroboros-irm PROPERTIES
+  VERSION ${PACKAGE_VERSION}
+  SOVERSION ${PACKAGE_VERSION_MAJOR}.${PACKAGE_VERSION_MINOR})
+
+ouroboros_target_debug_definitions(ouroboros-irm)
+
+target_include_directories(ouroboros-irm
+  PUBLIC
+    $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
+    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
+  PRIVATE
+    ${CMAKE_CURRENT_SOURCE_DIR}
+    ${CMAKE_CURRENT_BINARY_DIR}
+    ${CMAKE_BINARY_DIR}
+    ${SYS_RND_HDR})
+
+target_link_libraries(ouroboros-irm PUBLIC ouroboros-common)
+
+install(TARGETS ouroboros-irm
+  EXPORT OuroborosTargets
+  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
+
+configure_file("${CMAKE_CURRENT_SOURCE_DIR}/config.h.in"
+  "${CMAKE_CURRENT_BINARY_DIR}/config.h" @ONLY)
+
+configure_file("${CMAKE_CURRENT_SOURCE_DIR}/ssm/ssm.h.in"
+  "${CMAKE_CURRENT_BINARY_DIR}/ssm.h" @ONLY)
+
+if(BUILD_TESTS)
+  add_subdirectory(tests)
+  add_subdirectory(ssm/tests)
+endif()
diff --git a/src/lib/crypt.c b/src/lib/crypt.c
index 38dd9f29..8c29cbb3 100644
--- a/src/lib/crypt.c
+++ b/src/lib/crypt.c
@@ -20,6 +20,10 @@
  * Foundation, Inc., http://www.fsf.org/about/contact/.
  */
 
+#if defined(__linux__) || defined(__CYGWIN__)
+#define _DEFAULT_SOURCE
+#endif
+
 #include <config.h>
 
 #include <ouroboros/errno.h>
diff --git a/src/lib/ssm/tests/CMakeLists.txt b/src/lib/ssm/tests/CMakeLists.txt
index 827f8bf8..5cac70d1 100644
--- a/src/lib/ssm/tests/CMakeLists.txt
+++ b/src/lib/ssm/tests/CMakeLists.txt
@@ -18,16 +18,5 @@ target_link_libraries(${PARENT_DIR}_test ouroboros-common)
 
 add_dependencies(build_tests ${PARENT_DIR}_test)
 
-set(tests_to_run ${${PARENT_DIR}_tests})
-if(CMAKE_VERSION VERSION_LESS "3.29.0")
-  remove(tests_to_run test_suite.c)
-else ()
-  list(POP_FRONT tests_to_run)
-endif()
-
-foreach (test ${tests_to_run})
-  get_filename_component(test_name ${test} NAME_WE)
-  add_test(${TEST_PREFIX}/${test_name} ${C_TEST_PATH}/${PARENT_DIR}_test ${test_name})
-  set_property(TEST ${TEST_PREFIX}/${test_name}
-               PROPERTY ENVIRONMENT "OUROBOROS_TEST_POOL_SUFFIX=.test")
-endforeach (test)
+ouroboros_register_tests(TARGET ${PARENT_DIR}_test TESTS ${${PARENT_DIR}_tests}
+  ENVIRONMENT "OUROBOROS_TEST_POOL_SUFFIX=.test")
diff --git a/src/lib/tests/CMakeLists.txt b/src/lib/tests/CMakeLists.txt
index d2535bc2..23d01f9b 100644
--- a/src/lib/tests/CMakeLists.txt
+++ b/src/lib/tests/CMakeLists.txt
@@ -28,20 +28,4 @@ target_link_libraries(${PARENT_DIR}_test ouroboros-common)
 
 add_dependencies(build_tests ${PARENT_DIR}_test)
 
-set(tests_to_run ${${PARENT_DIR}_tests})
-if(CMAKE_VERSION VERSION_LESS "3.29.0")
-  remove(tests_to_run test_suite.c)
-else ()
-  list(POP_FRONT tests_to_run)
-endif()
-
-foreach (test ${tests_to_run})
-  get_filename_component(test_name ${test} NAME_WE)
-  add_test(${TEST_PREFIX}/${test_name} ${CMAKE_CURRENT_BINARY_DIR}/${PARENT_DIR}_test ${test_name})
-endforeach (test)
-
-set_property(TEST ${TEST_PREFIX}/auth_test PROPERTY SKIP_RETURN_CODE 1)
-set_property(TEST ${TEST_PREFIX}/auth_test_pqc PROPERTY SKIP_RETURN_CODE 1)
-set_property(TEST ${TEST_PREFIX}/crypt_test PROPERTY SKIP_RETURN_CODE 1)
-set_property(TEST ${TEST_PREFIX}/kex_test PROPERTY SKIP_RETURN_CODE 1)
-set_property(TEST ${TEST_PREFIX}/kex_test_pqc PROPERTY SKIP_RETURN_CODE 1)
+ouroboros_register_tests(TARGET ${PARENT_DIR}_test TESTS ${${PARENT_DIR}_tests})
diff --git a/src/tools/CMakeLists.txt b/src/tools/CMakeLists.txt
new file mode 100644
index 00000000..3cec8172
--- /dev/null
+++ b/src/tools/CMakeLists.txt
@@ -0,0 +1,71 @@
+# Tools build configuration
+
+set(TOOLS_INCLUDE_DIRS
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${CMAKE_SOURCE_DIR}/include
+  ${CMAKE_BINARY_DIR}/include
+)
+
+set(IRM_SOURCES
+  irm/irm.c
+  irm/irm_bind_program.c
+  irm/irm_bind_process.c
+  irm/irm_bind_ipcp.c
+  irm/irm_ipcp_create.c
+  irm/irm_ipcp_destroy.c
+  irm/irm_ipcp_bootstrap.c
+  irm/irm_ipcp_enroll.c
+  irm/irm_ipcp_list.c
+  irm/irm_ipcp_connect.c
+  irm/irm_ipcp_disconnect.c
+  irm/irm_unbind_program.c
+  irm/irm_unbind_process.c
+  irm/irm_unbind_ipcp.c
+  irm/irm_unbind.c
+  irm/irm_bind.c
+  irm/irm_ipcp.c
+  irm/irm_name.c
+  irm/irm_name_create.c
+  irm/irm_name_destroy.c
+  irm/irm_name_reg.c
+  irm/irm_name_unreg.c
+  irm/irm_name_list.c
+  irm/irm_utils.c
+)
+
+add_executable(irm ${IRM_SOURCES})
+target_include_directories(irm PRIVATE ${TOOLS_INCLUDE_DIRS})
+target_link_libraries(irm PRIVATE ouroboros-irm)
+install(TARGETS irm RUNTIME DESTINATION ${CMAKE_INSTALL_SBINDIR})
+
+add_executable(oping oping/oping.c)
+target_include_directories(oping PRIVATE ${TOOLS_INCLUDE_DIRS})
+target_link_libraries(oping PRIVATE ${LIBM_LIBRARIES} ouroboros-dev)
+install(TARGETS oping RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
+
+add_executable(oecho oecho/oecho.c)
+target_include_directories(oecho PRIVATE ${TOOLS_INCLUDE_DIRS})
+target_link_libraries(oecho PRIVATE ouroboros-dev)
+install(TARGETS oecho RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
+
+add_executable(ocbr ocbr/ocbr.c)
+target_include_directories(ocbr PRIVATE ${TOOLS_INCLUDE_DIRS})
+target_link_libraries(ocbr PRIVATE ouroboros-dev)
+install(TARGETS ocbr RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
+
+add_executable(obc obc/obc.c)
+target_include_directories(obc PRIVATE ${TOOLS_INCLUDE_DIRS})
+target_link_libraries(obc PRIVATE ouroboros-dev)
+install(TARGETS obc RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
+
+add_executable(operf operf/operf.c)
+target_include_directories(operf PRIVATE ${TOOLS_INCLUDE_DIRS})
+target_link_libraries(operf PRIVATE ouroboros-dev)
+install(TARGETS operf RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
+
+if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
+  add_executable(ovpn ovpn/ovpn.c)
+  target_include_directories(ovpn PRIVATE ${TOOLS_INCLUDE_DIRS})
+  target_link_libraries(ovpn PRIVATE ouroboros-dev)
+  install(TARGETS ovpn RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
+endif()